Code [Help] Constant Fire Sound/Animation Limitation

[FluX]

Here's the whole of the basekfweapon.uc if it helps:

Spoiler!

//=============================================================================
// BaseKFWeapon
//=============================================================================
// Base class for Killing Floor weapon functionality that needs native code.
//=============================================================================
// Killing Floor Source
// Copyright (C) 2009 Tripwire Interactive LLC
// - John "Ramm-Jaeger" Gibson
//=============================================================================
class BaseKFWeapon extends Weapon
 native
 abstract;
/*********************************************************************************************
 Zooming
********************************************************************************************* */
// Ironsights
var(Zooming) float  PlayerIronSightFOV;  // The fov to use for this weapon when in ironsights
var    bool  bZoomingIn;    // We are transitioning to zoomed in. When set to true native code will attempt to interpolate to the zoomed in ironsight position
var    bool  bZoomingOut;   // We are transitioning to zoomed out. When set to true native code will attempt to interpolate to the zoomed out ironsight position
var(Zooming) float  ZoomTime;    // How long the transition to/from iron sights should take
var(Zooming) rotator  ZoomInRotation;   // Amount to rotate to when zooming in to give the feeling of an animation playing
var    rotator  ZoomRotInterp;   // Set by the native code when zooming in/out. This is the interpolated rotation over time of the value set in ZoomInRotation
var    vector  ZoomStartOffset;  // When we start zooming what player view location is the first person weapon in. Used by the native code to calculate where to start zooming from
var    bool  bZoomInInterrupted;  // We were zooming in and it was interrupted. Used by the native code to handle smooth interpolations between zoomed positions
var    bool  bZoomOutInterrupted; // We were zooming out and it was interrupted. Used by the native code to handle smooth interpolations between zoomed positions
var    float  ZoomPartialTime;  // How much time we have to finish a partial zoom out. Used by the native code to handle smooth interpolations between zoomed positions
var    rotator  ZoomRotStartOffset;  // When we start zooming what rotation offset is the weapon. Used by the native code to handle smooth interpolations between zoomed positions
var    float  LastZoomOutTime;  // The last time we zoomed out. Used by the native code to determine if we can go to shouldered.
var(Zooming) float  FastZoomOutTime;  // How long to take to zoom out when we're doing a fast zoom out (i.e. when an action like reloading interupts ironsights)
var             bool        bFastZoomOut;           // The weapon is doing a fast zoom out without animating, and won't get ZoomStart/End Notifies
var             float       ZoomStartDisplayFOV;    // What is the DisplayFOV when we start zooming
var(Zooming)    float       ZoomedDisplayFOV;       // What is the DisplayFOV when zoomed in
// (cpptext)
// (cpptext)
// (cpptext)
// (cpptext)
replication
{
 reliable if(Role < ROLE_Authority)
  ServerZoomIn,ServerZoomOut;
}
/**
 * Handles the logic of which zoom functions to call based on if
 * we are a client or a server
 *
 * @param bZoomStatus which direction we are zooming
 */
simulated function PerformZoom(bool bZoomStatus)
{
 if( bZoomStatus )
 {
  if( Instigator.Physics == PHYS_Falling )
   return;
  ZoomIn(true);
  if( Role < ROLE_Authority)
   ServerZoomIn(false);
 }
 else
 {
  ZoomOut(true);
  if( Role < ROLE_Authority)
   ServerZoomOut(false);
 }
}
/**
 * Handles all the functionality for zooming in including
 * setting the parameters for the weapon, pawn, and playercontroller
 *
 * @param bAnimateTransition whether or not to animate this zoom transition
 */
simulated function ZoomIn(bool bAnimateTransition)
{
 if( bAnimateTransition )
 {
  // If the zoom out was interrupted, set the parameters for the native code to interpolate the zoom from the proper position
  if( bZoomingOut )
  {
   bZoomingOut=false;
   // Flag so the native code knows the zoom was interupted
   bZoomOutInterrupted=true;
   // Set the zoom time relative to how far along we were when zooming out
   ZoomTime=default.ZoomTime - ZoomTime;
   // Let the native code know where/when the zoom was interrupted
   ZoomPartialTime=ZoomTime;
   ZoomStartOffset=PlayerViewOffset;
   ZoomRotStartOffset=ZoomRotInterp;
   ZoomStartDisplayFOV=DisplayFOV;
  }
  else
  {
   ZoomTime=default.ZoomTime;
   ZoomStartOffset=PlayerViewOffset;
   ZoomStartDisplayFOV=DisplayFOV;
  }
  bZoomingIn=true;
 }
}
/**
 * Handles calling the zoom in function on the server
 *
 * @param bAnimateTransition whether or not to animate this zoom transition
 */
function ServerZoomIn(bool bAnimateTransition)
{
 ZoomIn(bAnimateTransition);
}
/**
 * Handles all the functionality for zooming out including
 * setting the parameters for the weapon, pawn, and playercontroller
 *
 * @param bAnimateTransition whether or not to animate this zoom transition
 */
simulated function ZoomOut(bool bAnimateTransition)
{
 if( bAnimateTransition )
 {
  // If the zoom in was interrupted, set the parameters for the native code to interpolate the zoom from the proper position
  if( bZoomingIn )
  {
   bZoomingIn=false;
   // Flag so the native code knows the zoom was interupted
   bZoomInInterrupted=true;
   // Set the zoom time relative to how far along we were when zooming in
   ZoomTime=default.ZoomTime - ZoomTime;
   // Let the native code know where/when the zoom was interrupted
   ZoomPartialTime=ZoomTime;
   ZoomStartOffset=PlayerViewOffset;
   ZoomRotStartOffset=ZoomRotInterp;
   ZoomStartDisplayFOV=DisplayFOV;
  }
  else
  {
   ZoomTime=default.ZoomTime;
  }
  bZoomingOut=true;
 }
 else
 {
        // do a fast zoomout with no notifies
        bFastZoomOut = true;
  // If the zoom in was interrupted, set the parameters for the native code to interpolate the zoom from the proper position
  if( bZoomingIn )
  {
   bZoomingIn=false;
   // Flag so the native code knows the zoom was interupted
   bZoomInInterrupted=true;
   // Set the zoom time relative to how far along we were when zooming in
   ZoomTime=default.ZoomTime - ZoomTime;
   // Let the native code know where/when the zoom was interrupted
   ZoomPartialTime=ZoomTime;
   ZoomStartOffset=PlayerViewOffset;
   ZoomRotStartOffset=ZoomRotInterp;
   ZoomStartDisplayFOV=DisplayFOV;
  }
  else
  {
   ZoomTime=FastZoomOutTime;
  }
  bZoomingOut=true;
  LastZoomOutTime=Level.TimeSeconds+ZoomTime;
 }
}
/**
 * Handles calling the zoom out function on the server
 *
 * @param bAnimateTransition whether or not to animate this zoom transition
 */
function ServerZoomOut(bool bAnimateTransition)
{
 ZoomOut(bAnimateTransition);
}
 
/**
 * Called by the native code when the interpolation of the first person weapon to the zoomed position finishes
 */
simulated event OnZoomInFinished(){}
/**
 * Called by the native code when the interpolation of the first person weapon from the zoomed position finishes
 */
simulated event OnZoomOutFinished(){}
defaultproperties
{
     PlayerIronSightFOV=75.000000
     ZoomTime=0.250000
     ZoomInRotation=(Pitch=-910,Roll=2910)
     FastZoomOutTime=0.200000
     ZoomedDisplayFOV=75.000000
}

Sorry don't know what exactly to look for.

 

[braindead]

Flux look at my last post on the page 1. it fixes the view for you

 

[YoYoBatty]

The MP7 uses a fire loop and fire end sound as well as various bits of code responsible for the animation, it works exactly like extremely fast firing guns in red orchestra like the machine guns, when you switch to semi auto fire the reason why the gun looks like it's firing is because it goes into the firing loop state. I've tried to do the exact same thing you are trying to do and it did not end well. I could probably help you with this but your best bet is completely rewritting the code.

 

[ro_sauce]

i'm still having the problem with my mg34.
the fullauto uses the fireloop/end anims & ambientsound/end sounds.
there are single fire sounds and anims that i use for semiauto, but they act like the loop/ambient stuff, while only shooting once.
that was with mg34 extends mp7, mg34fire extends mp7 fire.

next i tried mg34 extends ak47, with firemode0=mg34fire (extends mp7), firemode1=mg34singlefire (extends deaglefire), and now the anims all work, but when i shoot a singlefire, it toggles the primary fire to semi.

so then i did mg34 extends kfweapon, and now the primary doesnt do squat. alt fire works fine though.


code:
http://www.gamefront.com/files/20685091/mg34classes.7z

 

[FluX]

Right all I did was copy the AKAssaultrifle.uc and changed the Mesh/Skins to:

     Mesh=SkeletalMesh'KF_Weapons2_Trip.MP7_Trip'
     Skins(0)=Shader'FluxMP7_T.MP7_Final'
     Skins(1)=texture'FluxMP7_T.Dot'

It still does the same thing...

Screenshot here of it.

Here's the defaultproperties of my file for as nothing else has been changed:

defaultproperties
{
     MagCapacity=30
     ReloadRate=3.000000
     ReloadAnim="Reload"
     ReloadAnimRate=1.000000
     WeaponReloadAnim="Reload_AK47"
     HudImage=Texture'KillingFloor2HUD.WeaponSelect.Ak_47_unselected'
     SelectedHudImage=Texture'KillingFloor2HUD.WeaponSelect.Ak_47'
     Weight=6.000000
     bHasAimingMode=True
     IdleAimAnim="Idle_Iron"
     StandardDisplayFOV=60.000000
     bModeZeroCanDryFire=True
     TraderInfoTexture=Texture'KillingFloor2HUD.Trader_Weapon_Icons.Trader_AK_47'
     bIsTier2Weapon=True
     PlayerIronSightFOV=65.000000
     ZoomedDisplayFOV=32.000000
     FireModeClass(0)=Class'KFMod.AK47Fire'
     FireModeClass(1)=Class'KFMod.NoFire'
     PutDownAnim="PutDown"
     SelectSound=Sound'KF_AK47Snd.AK47_Select'
     SelectForce="SwitchToAssaultRifle"
     AIRating=0.550000
     CurrentRating=0.550000
     bShowChargingBar=True
     Description="A classic Russian assault rifle. Can be fired in semi or full auto with nice knock down power but not great accuracy."
     EffectOffset=(X=100.000000,Y=25.000000,Z=-10.000000)
     DisplayFOV=60.000000
     SleeveNum=2
     Priority=5
     CustomCrosshair=11
     CustomCrossHairTextureName="Crosshairs.HUD.Crosshair_Cross5"
     InventoryGroup=3
     GroupOffset=4
     PickupClass=Class'KFMod.AK47Pickup'
     PlayerViewOffset=(X=18.000000,Y=22.000000,Z=-6.000000)
     BobDamping=6.000000
     AttachmentClass=Class'KFMod.AK47Attachment'
     IconCoords=(X1=245,Y1=39,X2=329,Y2=79)
     ItemName="AK47"
     Mesh=SkeletalMesh'KF_Weapons2_Trip.MP7_Trip'
     Skins(0)=Shader'FluxMP7_T.MP7_Final'
     Skins(1)=texture'FluxMP7_T.Dot'
     TransientSoundVolume=1.250000
}

 

[braindead]

Flux I did explain to add Prepivot=(z=5)

but i don't see it in there?

actually i found z=6 is better, lines up perfectly

 

[ro_sauce]

ok i got the full/semi fire working, without toggle.
but now my reload anims dont work... and full auto sounds are not playing... and it wont go to ironsights.

 

[braindead]

ro are you trying to get yours to work like the AK? so it has rapid and semi auto fire?

 

[FluX]

Flux I did explain to add Prepivot=(z=5)

but i don't see it in there?

actually i found z=6 is better, lines up perfectly

Mate you never said this even in the PM I'll try this now.

RO doesn't want a toggle like the AK47. He wants two seperate fire modes, one is one speed, one is another. That's what I think he wants anyway.

 

[braindead]

Mate you never said this even in the PM I'll try this now.

RO doesn't want a toggle like the AK47. He wants two seperate fire modes, one is one speed, one is another. That's what I think he wants anyway.

lol i mentioned in the post with the pic, look at my last post on the 1st page.

 

[FluX]

lol i mentioned in the post with the pic, look at my last post on the 1st page.

Ah damn sorry mate I hadn't seen this at all My apologise.

 

[ro_sauce]

the mg34 has loopanim and and ambient sounds for fullauto fire. so i nabbed the mp7/mp7fire code for those functions and defaults.

the semiauto has a singlefire anim and singlefire sound, separate from the looped ones.
so when i use them with the mp7 code, they loop, so instead of using the ak47 toggle switch, i use
firemode0=fullautofire
firemode1=semifire

semifire now extends bullpupsemifire, and it works good.
fullauto i am now having problems with, the sound wont play.
and the reload anims wont play.
and it wont reload now.


mg34.uc

Spoiler!

class mg34 extends kfweapon;

#exec OBJ LOAD FILE=mgtex.utx
#exec OBJ LOAD FILE=KillingFloorHUD.utx
#exec OBJ LOAD FILE=Inf_Weapons_Foley.uax
#exec OBJ LOAD FILE=inf_weapons.uax

simulated function bool StartFire(int Mode)
{
if( Mode == 1 )
return super.StartFire(Mode);

if( !super.StartFire(Mode) ) // returns false when mag is empty
return false;

if( AmmoAmount(0) <= 0 )
{
return false;
}

AnimStopLooping();

if( !FireMode[Mode].IsInState('FireLoop') && (AmmoAmount(0) > 0) )
{
FireMode[Mode].StartFiring();
return true;
}
else
{
return false;
}

return true;
}

simulated function AnimEnd(int channel)
{
local name anim;
local float frame, rate;

if(!FireMode[0].IsInState('FireLoop'))
{
GetAnimParams(0, anim, frame, rate);

if (ClientState == WS_ReadyToFire)
{
if ((FireMode[0] == None || !FireMode[0].bIsFiring) && (FireMode[1] == None || !FireMode[1].bIsFiring))
{
PlayIdle();
}
}
}
}

simulated function bool CanZoomNow()
{
Return (!FireMode[0].bIsFiring && Instigator!=None && Instigator.Physics!=PHYS_Falling);
}

defaultproperties
{
MagCapacity=50
ReloadRate=7.0300000
ReloadAnim="Bipod_Reload"
FlashBoneName="Muzzle"
WeaponReloadAnim="Bipod_Reload"
HudImage=Texture'mgtex.mg34_icon'
SelectedHudImage=Texture'mgtex.mg34_icon_select'
Weight=5.000000
IdleAimAnim="bipod_Idle"
StandardDisplayFOV=60.000000
SleeveNum=7
TraderInfoTexture=Texture'mgtex.mg34_icon'
ZoomedDisplayFOV=32.000000
FireModeClass(0)=Class'serverperksv4.mg34Fire'
FireModeClass(1)=Class'serverperksv4.mg34singlefire'
PutDownAnim="Putaway"
SelectSound=Sound'KF_AK47Snd.AK47_Select'
Description="Precursor to the MG42."
EffectOffset=(X=120.000000,Y=10.000000,Z=-30.000000)
DisplayFOV=60.000000
Priority=5
CustomCrosshair=11
CustomCrossHairTextureName="Crosshairs.HUD.Crosshair_Cross5"
GroupOffset=4
PickupClass=Class'serverperksv4.mg34Pickup'
PlayerViewOffset=(X=2,Y=2.500000,Z=-1)
BobDamping=4.000000
AttachmentClass=Class'serverperksv4.mg34attachment'
ItemName="MG34"
Mesh=SkeletalMesh'mganims.MG_34'
Skins(0)=Texture'mgtex.hands'
Skins(1)=Texture'mgtex.Arms'
Skins(2)=Shader'mgtex.mg34shd'
Skins(3)=Shader'mgtex.mgbipodshd'
}

mg34fire.uc

Spoiler!

class mg34fire extends bullpupfire;

#exec OBJ LOAD FILE=mgtex.utx
#exec OBJ LOAD FILE=KillingFloorHUD.utx
#exec OBJ LOAD FILE=Inf_Weapons_Foley.uax
#exec OBJ LOAD FILE=Inf_Weapons.uax

// sound
var sound FireEndSound; // The sound to play at the end of the ambient fire sound
var sound FireEndStereoSound; // The sound to play at the end of the ambient fire sound in first person stereo
var float AmbientFireSoundRadius; // The sound radius for the ambient fire sound
var sound AmbientFireSound; // How loud to play the looping ambient fire sound
var byte AmbientFireVolume; // The ambient fire sound

// Sends the fire class to the looping state
function StartFiring()
{
GotoState('FireLoop');
}

// Handles toggling the weapon attachment's ambient sound on and off
function PlayAmbientSound(Sound aSound)
{
local WeaponAttachment WA;

WA = WeaponAttachment(Weapon.ThirdPersonActor);

if ( Weapon == none || (WA == none))
return;

if(aSound == None)
{
WA.SoundVolume = WA.default.SoundVolume;
WA.SoundRadius = WA.default.SoundRadius;
}
else
{
WA.SoundVolume = AmbientFireVolume;
WA.SoundRadius = AmbientFireSoundRadius;
}

WA.AmbientSound = aSound;
}

// Make sure we are in the fire looping state when we fire
event ModeDoFire()
{
if( AllowFire() && IsInState('FireLoop'))
{
Super.ModeDoFire();
}
}


/* =================================================================================== *
* FireLoop
* This state handles looping the firing animations and ambient fire sounds as well
* as firing rounds.
*
* modified by: Ramm 1/17/05
* =================================================================================== */
state FireLoop
{
function BeginState()
{
NextFireTime = Level.TimeSeconds - 0.1; //fire now!

if( KFWeap.bAimingRifle )
{
Weapon.LoopAnim(FireLoopAimedAnim, FireLoopAnimRate, TweenTime);
}
else
{
Weapon.LoopAnim(FireLoopAnim, FireLoopAnimRate, TweenTime);
}

PlayAmbientSound(AmbientFireSound);
}

// Overriden because we play an anbient fire sound
function PlayFiring() {}
function ServerPlayFiring() {}

function EndState()
{
Weapon.AnimStopLooping();
PlayAmbientSound(none);
if( Weapon.Instigator != none && Weapon.Instigator.IsLocallyControlled() &&
Weapon.Instigator.IsFirstPerson() && StereoFireSound != none )
{
Weapon.PlayOwnedSound(FireEndStereoSound,SLOT_None,AmbientFireVolume/127,,AmbientFireSoundRadius,,false);
}
else
{
Weapon.PlayOwnedSound(FireEndSound,SLOT_None,AmbientFireVolume/127,,AmbientFireSoundRadius);
}
Weapon.StopFire(ThisModeNum);
}

function StopFiring()
{
GotoState('');
}

function ModeTick(float dt)
{
Super.ModeTick(dt);

if ( !bIsFiring || !AllowFire() ) // stopped firing, magazine empty
{
GotoState('');
return;
}
}
}

defaultproperties
{
FireEndSound=SoundGroup'Inf_Weapons.mg34.mg34_fire_end'
AmbientFireSound=SoundGroup'Inf_Weapons.mg34.mg34_fire_loop'
AmbientFireVolume=2
FireAimedAnim="Bipod_shoot_loop"
FireEndAimedAnim="Bipod_Shoot_End"
FireLoopAimedAnim="Bipod_Shoot_Loop"
RecoilRate=0.030000
maxVerticalRecoilAngle=350
maxHorizontalRecoilAngle=10
ShellEjectBoneName="ejector"
DamageType=Class'KFMod.DamTypeDeagle'
DamageMin=50
DamageMax=65
Momentum=10000.000000
FireLoopAnim="Bipod_Shoot_Loop"
FireEndAnim="Bipod_Shoot_End"
TweenTime=0.000000
//FireSound=
FireRate=0.070000
AmmoClass=Class'serverperksv4.mg34Ammo'
ShakeRotMag=(X=50.000000,Y=50.000000,Z=50.000000)
ShakeRotTime=2.000000
ShakeOffsetMag=(X=3.000000,Y=1.000000,Z=3.000000)
ShakeOffsetTime=2.000000
aimerror=10.000000
Spread=0.006000
}

mg34singlefire.uc

Spoiler!

class mg34singlefire extends bullpupsemifire;

defaultproperties
{
FireAimedAnim="bipod_shoot_single"
KickMomentum=(X=-1.500000,Z=1.000000)
RecoilRate=0.030000
maxVerticalRecoilAngle=350
maxHorizontalRecoilAngle=10
ShellEjectClass=Class'ROEffects.KFShellEjectHandCannon'
ShellEjectBoneName="ejector"
StereoFireSound=SoundGroup'Inf_Weapons.mg34.mg34_fire_single'
DamageType=Class'KFMod.DamTypeDeagle'
DamageMin=50
DamageMax=65
Momentum=10000.000000
bPawnRapidFireAnim=True
bWaitForRelease=True
TransientSoundVolume=1.800000
TweenTime=0.00000
FireSound=SoundGroup'Inf_Weapons.mg34.mg34_fire_single'
FireForce="AssaultRifleFire"
FireRate=0.110000
AmmoClass=Class'serverperksv4.mg34Ammo'
AmmoPerFire=1
ShakeRotMag=(X=75.000000,Y=75.000000,Z=400.000000)
ShakeRotRate=(X=12500.000000,Y=12500.000000,Z=10000.000000)
ShakeRotTime=3.500000
ShakeOffsetMag=(X=6.000000,Y=1.000000,Z=8.000000)
ShakeOffsetRate=(X=1000.000000,Y=1000.000000,Z=1000.000000)
ShakeOffsetTime=2.500000
BotRefireRate=0.650000
FlashEmitterClass=Class'ROEffects.MuzzleFlash1stKar'
aimerror=0.000000
}

 

[braindead]

You need FireEndStereoSound= in there for a start, this is the 1st person fire sound.
Just looking through to see why it won't reload for you.


question....

did you rename the anims yourself, i.e. Bipod_reload? because looking in the animations in ro, the reload anim is called 'reload'

 

[ro_sauce]

that is what the mg34 reload is named, in animations->mg34+mg34 animation set, there are two reload animations.
bipod_reload
bipod_reload_s
they seem to me to be exactly the same.
maybe changing fireendstereosound will fix the sound.

why do you think i cant zoom in now? (ironsights)

 

[YoYoBatty]

that is what the mg34 reload is named, in animations->mg34+mg34 animation set, there are two reload animations.
bipod_reload
bipod_reload_s
they seem to me to be exactly the same.
maybe changing fireendstereosound will fix the sound.

why do you think i cant zoom in now? (ironsights)

Because the way iron sights work in red orchestra is different from killing floor

 

[ro_sauce]

all the other mg's i ported work fine, i didnt extend the mg34 from any ro_classes, it is all under kfweapon/kfweaponfire, and modified to use fireloopanims/ambientsouns function nabbed from mp7m classes.

as far as i can tell, all the ironsights do in kf is zoom and move the mesh's prepivot to center of screen.

 

[YoYoBatty]

all the other mg's i ported work fine, i didnt extend the mg34 from any ro_classes, it is all under kfweapon/kfweaponfire, and modified to use fireloopanims/ambientsouns function nabbed from mp7m classes.

as far as i can tell, all the ironsights do in kf is zoom and move the mesh's prepivot to center of screen.

Not exactly it's prepivot but the actually location of the gun which is known as the PlayerViewOffset

 

[ro_sauce]

did you take a look at the code i posted above (in the spoilers) ?

can you tell me what function is screwing up where the ambient fire sound in mg34fire wont play, the reload anim wont play, and i cant go to ironsights?
http://forums.tripwireinteractive.com/showpost.php?p=797341&postcount=32

 

[YoYoBatty]

You don't need to extend BullpupSemiFire, it doesn't do anything, you could have just extended KFFire and put bWaitForRelease=True in the defaultproperties

 

[ro_sauce]

well, i gave up for now, its fine if the semifire loops, doesnt affect gameplay.