Unlimited Ammo - Mutator Help

[Tendency]

I am using this mutator but it generates the following two errors making the log file massive.

Warning: MutAmmo KF-Bedlam.MutAmmo (Function MutAmmo.MutAmmo.GiveAmmo:001C) Accessed None 'Human'
Warning: MutAmmo KF-Bedlam.MutAmmo (Function MutAmmo.MutAmmo.GiveAmmo:001C) Accessed None 'Human'
Warning: MutAmmo KF-Bedlam.MutAmmo (Function MutAmmo.MutAmmo.GiveAmmo:001C) Accessed None 'Human'
Warning: MutAmmo KF-Bedlam.MutAmmo (Function MutAmmo.MutAmmo.GiveAmmo:001C) Accessed None 'Human'
Warning: MutAmmo KF-Bedlam.MutAmmo (Function MutAmmo.MutAmmo.GiveAmmo:001C) Accessed None 'Human'
Warning: MutAmmo KF-Bedlam.MutAmmo (Function MutAmmo.MutAmmo.GiveAmmo:003E) Accessed None 'Inv'
Warning: MutAmmo KF-Bedlam.MutAmmo (Function MutAmmo.MutAmmo.GiveAmmo:0051) Accessed None 'Inv'
Warning: MutAmmo KF-Bedlam.MutAmmo (Function MutAmmo.MutAmmo.GiveAmmo:003E) Accessed None 'Inv'

I would like to fix it. But i am not a coder. I have no problems decompiling or compiling, just dont understand the structure of classes. Sometimes i can get lucky and make the correct changes, but not this time. Here is the code.

//=============================================================================
// MutAmmo - Unlimited 9mm ammo - By EvilDooinz aka Bruce303lee
//=============================================================================
class MutAmmo extends Mutator;
event PreBeginPlay()
{
SetTimer(1.0,true);
}
 
function Timer()
{
local Controller C;
 
for (C = Level.ControllerList; C != None; C = C.NextController)
{
ModifyPawn(C.Pawn);
}
}
static simulated function ModifyPawn(Pawn Other)
{
local int AddAmmo;
AddAmmo = 10 + Rand(51);
GiveAmmo(Other, AddAmmo);
}
static function GiveAmmo(Pawn pawn,float Percentage)
{
local KFHumanPawn human;
Local Inventory Inv;
human = KFHumanPawn(pawn);
for (Inv = human.Inventory; Inv != None; Inv = Inv.Inventory)
{
if (KFAmmunition(Inv).AmmoAmount < KFAmmunition(Inv).MaxAmmo)
KFAmmunition(Inv).AmmoAmount = KFAmmunition(Inv).MaxAmmo;
}
}
defaultproperties
{
GroupName="KF-Ammo"
FriendlyName="Ammo Regen"
Description="All weapons have unlimited ammunition"
}

 

[Benjamin]

You need to check that 'human' and 'inv' are not none before you access them, otherwise you will get these warnings.

 

[Tendency]

Thanks again Benjamin.

 

[Tendency]

How can you "exclude" an item from being regenerated, e.g. Frags + Pipebombs.

I want to provide unlimited ammo for all weapons except for frags and pipebombs. Would this be a case to use the "ignores" function or "else if".

 

[Marco]

Simply like this:

static function GiveAmmo(Pawn pawn,float Percentage)
{
    Local Inventory Inv;

    if( pawn==None )
        return;
    for (Inv = pawn.Inventory; Inv != None; Inv = Inv.Inventory)
    {
        if ( KFAmmunition(Inv)!=None && [COLOR=Red]FragAmmo(inv)==None[/COLOR] && [COLOR=Red]PipeBombAmmo(inv)==None[/COLOR]
         && KFAmmunition(Inv).AmmoAmount<KFAmmunition(Inv).MaxAmmo )
            KFAmmunition(Inv).AmmoAmount = KFAmmunition(Inv).MaxAmmo;
    }
}

 

[Tendency]

Thanks a million Marco. I appreciate your help and all the fine Mutators you have made for us.

 

[Rioku]

I have a question, is it possible to make it to where all weapons, including custom weapons, have unlimited ammo?

 

[matttthias]

this code already includes custom weapons

 

[Rioku]

Thank you! How do I implement it though? I have a version that only replenishes the 9mm and a select few other weapons.

 

[Rioku]

Thank you!! I just have one question, how would you implement this? I have a version that someone made already but it only works for a few weapons such as the MP7, 9mm, and I believe that's it.

 

[Excalibolg]

This is the code I use on my server. Refills the ammo of every weapon but grenades and pipebombs.

class GliderAmmo extends Mutator;

event PreBeginPlay()
{
    SetTimer(1.0,true);
}
 
function Timer()
{
    local Controller C;
 
    for (C = Level.ControllerList; C != None; C = C.NextController)
    {
        ModifyPawn(C.Pawn);
    }
}

static simulated function ModifyPawn(Pawn pawn)
{
    GiveAmmo(pawn);
}

static function GiveAmmo(Pawn pawn)
{
    local KFHumanPawn human;
    Local Inventory Inv;

    human = KFHumanPawn(pawn);
    
    if (human != None)
    {
        for (Inv = human.Inventory; Inv != None; Inv = Inv.Inventory)
        {
            if (Inv != None)
            {
                if ( KFAmmunition(Inv) != None && (FragAmmo(Inv) == None) && (PipeBombAmmo(Inv) == None) && (KFAmmunition(Inv).AmmoAmount < KFAmmunition(Inv).MaxAmmo) )
                {
                   KFAmmunition(Inv).AmmoAmount = KFAmmunition(Inv).MaxAmmo;
                }
            }
        }
    }
}

defaultproperties
{
     GroupName="KF-GliderAmmo"
     FriendlyName="GliderAmmo"
     Description="Unlimited  ammunition"
}

 

[Rayman1103]

Can someone please release an unlimited ammo Mutator? I've tried to create a Mutator myself but I can't get it to compile. Also if it's possible make only the clips be unlimited, meaning I'd still like to reload.

 

[Tendency]

Can someone please release an unlimited ammo Mutator? I've tried to create a Mutator myself but I can't get it to compile. Also if it's possible make only the clips be unlimited, meaning I'd still like to reload.

[url]http://xgamersbr.forumeiros.com/t10-killing-floor-mods[/URL]

 

[Rayman1103]

<a href="http://xgamersbr.forumeiros.com/t10-killing-floor-mods" target="_blank">[url]http://xgamersbr.forumeiros.com/t10-killing-floor-mods[/URL]

Thank you very much! There's a lot of Mutators there that I've never even heard of before, many thanks.