Code [Request] xplosive rounds

[ChairmanMurder[Forge]]

So, I've been thinking of just using the code from the AA12 to make a new weapon for the Demo. Nothing fancy at all, just modified code, maybe a new name.

Anyhow, the title says it all, I think. I'm basically wondering how to code explosive rounds (say, FRAG-12) into an AA12. I was playing around with the WTFMod and they managed to code the AA12 (I think it's called ASF12 or something) to fire explosive rounds when wielded by a Demo.

I can make the mutator, but I'm utterly at a loss how to make the rounds explosive (i.e. they damage specimens as well as you if fired too close).

I've tried changing damage classes to the grenades, but no dice. When the specimen gets shot, he'll gib as if he's been hit by a grenade, but the others around him won't. I also don't take damage if I fire into the floor at my feet.

Anyway, for the TL;DR verion, I'm wondering what parameters to change to make shotgun "bullets" explosive.

Thanks for the help.

 

[Excalibolg]

Since you already brought up WTFMut: The AFS12 spawns custom Shotgun bullets that explode and deal damage in a radius

class WTFEquipAFS12ExplosiveRound extends ShotgunBullet;

var() array<Sound> ExplodeSounds;

simulated function Explode(vector HitLocation,vector HitNormal)
{
    if ( Role == ROLE_Authority )
    {
        HurtRadius(Damage*0.75, DamageRadius, MyDamageType, 0.0, HitLocation );
        HurtRadius(Damage*0.25, DamageRadius*2.0, MyDamageType, MomentumTransfer, HitLocation );
        
        //does full damage within DamageRadius (dealt in two chunks), but less damage to things outside of DamageRadius but within
        //DamageRadius*2.0
    }

    //why would it matter if instigator exists or not for spawning an fx???
    //if ( KFHumanPawn(Instigator) != none )
    //{
    
        PlaySound(ExplodeSounds[rand(ExplodeSounds.length)],,1.0);
        
        if ( EffectIsRelevant(Location,false) )
        {
            Spawn(class'WTF.WTFEquipAFS12ExplosiveRoundEmitter',self,,Location);
        }
        
    //}

    Destroy();
}

simulated function ProcessTouch (Actor Other, vector HitLocation)
{
    if ( Other != Instigator && !Other.IsA('PhysicsVolume') && (Other.IsA('Pawn') || Other.IsA('ExtendedZCollision')) )
    {
        Other.Velocity.X = Self.Velocity.X * 0.05;
        Other.Velocity.Y = Self.Velocity.Y * 0.05;
        Other.Velocity.Z = Self.Velocity.Z * 0.05;
        Other.Acceleration = vect(0,0,0); //0,0,0
        
        Explode(Other.Location,Other.Location);
    }
}

defaultproperties
{
     ExplodeSounds(0)=SoundGroup'KF_GrenadeSnd.Nade_Explode_1'
     ExplodeSounds(1)=SoundGroup'KF_GrenadeSnd.Nade_Explode_2'
     ExplodeSounds(2)=SoundGroup'KF_GrenadeSnd.Nade_Explode_3'
     Damage=250.000000
     DamageRadius=75.000000
     MomentumTransfer=1000.000000
     MyDamageType=Class'KFMod.DamTypeM79Grenade'
     StaticMesh=StaticMesh'kf_generic_sm.Bullet_Shells.40mm_Warhead'
     DrawScale=0.500000
}

 

[ChairmanMurder[Forge]]

It's what I'm trying, haha. I think I've pointed to all the right functions and renamed everything correctly, but the AA12-F still fires regular old AA12 shots.

 

[Excalibolg]

Well guessing can only get us so far. Did you change the properties of the fire method to fire your custom rounds? Did you override the fire method in your new gun correctly? Are you actually using a new gun or trying to override the vanilla AA12?

Post some code and this will go much quicker

 

[ChairmanMurder[Forge]]

Sorry for the lateness. I got it to work. However, since I just want a code change, and not the fancy textures and models of WTF, I deleted the relevant code pointing to the custom sprites or whatever they are. Are there any spirtes or something in stock KF that I can call up to make it a little more... flashy? In the WTFMod the Demo AA12 had these pretty white flashes that poofed up on impact. As of right now, they just... impact.

I mean, yeah, the zombies blow up and everything. But I need flash, haha. If it's impossible, no skin off my back. I'm just curious, is all.

EDIT: I'm thinking, the sparks that fly when you shoot metal, like the trader door. Any way to call those up?

 

[HaTeMe]

If it's impossible, no skin off my back. I'm just curious, is all.

No its not impossible at all, you just need to spawn an emitter when the bullets hit the target. I might be able to do it for you if I had the code.

 

[ChairmanMurder[Forge]]

So I have AA12f bullet (which is slightly modified from the WTF version:

Spoiler!

//=============================================================================
// AA12 Shotgun Bullet
//=============================================================================
class AA12FBullet extends ShotgunBullet;

var() array<Sound> ExplodeSounds;

simulated function Explode(vector HitLocation,vector HitNormal)
{
	if ( Role == ROLE_Authority )
	{
		HurtRadius(Damage*0.75, DamageRadius, MyDamageType, 0.0, HitLocation );
		HurtRadius(Damage*0.25, DamageRadius*2.0, MyDamageType, MomentumTransfer, HitLocation );
		
		//does full damage within DamageRadius (dealt in two chunks), but less damage to things outside of DamageRadius but within
		//DamageRadius*2.0
	}

	//why would it matter if instigator exists or not for spawning an fx???
	//if ( KFHumanPawn(Instigator) != none )
	//{
	
		PlaySound(ExplodeSounds[rand(ExplodeSounds.length)],,1.0);
		
		if ( EffectIsRelevant(Location,false) )
		{
			Spawn(class'AA12F.AA12FExplosiveRoundEmitter',self,,Location);
		}
		
	//}

	Destroy();
}

simulated function ProcessTouch (Actor Other, vector HitLocation)
{
	if ( Other != Instigator && !Other.IsA('PhysicsVolume') && (Other.IsA('Pawn') || Other.IsA('ExtendedZCollision')) )
	{
		Other.Velocity.X = Self.Velocity.X * 0.05;
		Other.Velocity.Y = Self.Velocity.Y * 0.05;
		Other.Velocity.Z = Self.Velocity.Z * 0.05;
		Other.Acceleration = vect(0,0,0); //0,0,0
		
		Explode(Other.Location,Other.Location);
	}
}

defaultproperties
{
     ExplodeSounds(0)=SoundGroup'KF_GrenadeSnd.Nade_Explode_1'
     ExplodeSounds(1)=SoundGroup'KF_GrenadeSnd.Nade_Explode_2'
     ExplodeSounds(2)=SoundGroup'KF_GrenadeSnd.Nade_Explode_3'
     Damage=200.000000
     DamageRadius=100.000000
     MomentumTransfer=1000.000000
     MyDamageType=Class'KFMod.DamTypeM79Grenade'
     StaticMesh=StaticMesh'kf_generic_sm.Bullet_Shells.40mm_Warhead'
     DrawScale=0.500000
}

The "class'AA12F.AA12FExplosiveRoundEmitter" in the bullet code points to this. The highlighted line near the bottom was deleted so I wouldn't have to call up external sprite files.

Spoiler!

class AA12FExplosiveRoundEmitter extends Emitter;

defaultproperties
{
     Begin Object Class=SpriteEmitter Name=Blast
         UseColorScale=True
         FadeOut=True
         RespawnDeadParticles=False
         SpinParticles=True
         UseSizeScale=True
         UniformSize=True
         BlendBetweenSubdivisions=True
         ColorScale(1)=(RelativeTime=0.300000,Color=(B=100,G=100,R=100))
         ColorScale(2)=(RelativeTime=0.500000,Color=(B=100,G=100,R=100))
         FadeOutStartTime=0.100000
         MaxParticles=50
         StartLocationShape=PTLS_Sphere
         SphereRadiusRange=(Min=1.000000,Max=1.000000)
         SpinsPerSecondRange=(X=(Min=0.100000,Max=0.100000),Y=(Min=0.100000,Max=0.100000),Z=(Min=0.100000,Max=0.100000))
         SizeScale(1)=(RelativeTime=0.010000,RelativeSize=1.000000)
         SizeScale(2)=(RelativeTime=0.100000,RelativeSize=5.000000)
         StartSizeRange=(X=(Min=15.000000,Max=15.000000),Y=(Min=15.000000,Max=15.000000),Z=(Min=15.000000,Max=15.000000))
         ParticlesPerSecond=500.000000
         Texture=Texture'kf_fx_trip_t.Misc.smoke_animated'
         TextureUSubdivisions=8
         TextureVSubdivisions=8
         LifetimeRange=(Min=0.150000,Max=0.150000)
         StartVelocityRange=(X=(Min=-300.000000,Max=300.000000),Y=(Min=-300.000000,Max=300.000000),Z=(Min=-300.000000,Max=300.000000))
     End Object
[COLOR="yellow"]     Emitters(2)=SpriteEmitter'WTF.WTFEquipAFS12ExplosiveRoundEmitter.Blast'[/COLOR]

     bNoDelete=False
     LifeSpan=0.250000
}

 

[HaTeMe]

Spoiler!

class AA12FExplosiveRoundEmitter extends Emitter;

defaultproperties
{
     Begin Object Class=SpriteEmitter Name=Blast
         UseColorScale=True
         FadeOut=True
         RespawnDeadParticles=False
         SpinParticles=True
         UseSizeScale=True
         UniformSize=True
         BlendBetweenSubdivisions=True
         ColorScale(1)=(RelativeTime=0.300000,Color=(B=100,G=100,R=100))
         ColorScale(2)=(RelativeTime=0.500000,Color=(B=100,G=100,R=100))
         FadeOutStartTime=0.100000
         MaxParticles=50
         StartLocationShape=PTLS_Sphere
         SphereRadiusRange=(Min=1.000000,Max=1.000000)
         SpinsPerSecondRange=(X=(Min=0.100000,Max=0.100000),Y=(Min=0.100000,Max=0.100000),Z=(Min=0.100000,Max=0.100000))
         SizeScale(1)=(RelativeTime=0.010000,RelativeSize=1.000000)
         SizeScale(2)=(RelativeTime=0.100000,RelativeSize=5.000000)
         StartSizeRange=(X=(Min=15.000000,Max=15.000000),Y=(Min=15.000000,Max=15.000000),Z=(Min=15.000000,Max=15.000000))
         ParticlesPerSecond=500.000000
         Texture=Texture'kf_fx_trip_t.Misc.smoke_animated'
         TextureUSubdivisions=8
         TextureVSubdivisions=8
         LifetimeRange=(Min=0.150000,Max=0.150000)
         StartVelocityRange=(X=(Min=-300.000000,Max=300.000000),Y=(Min=-300.000000,Max=300.000000),Z=(Min=-300.000000,Max=300.000000))
     End Object
[COLOR=yellow]     Emitters(2)=SpriteEmitter'WTF.WTFEquipAFS12ExplosiveRoundEmitter.Blast'[/COLOR]

     bNoDelete=False
     LifeSpan=0.250000
}

It seems to be using the default sprites/texture from KF so what you should do is simply rename the yellow line to correspond your own code I guess. Altho I simply used Emitters(2)=SpriteEmitter'Blast' in my own weapon code, not the exact form ofc but I didnt point it to any specific package. Basically its the emitter name from the top line where it says "Name=Blast".

You could try that.

Also if you have only 1 emitter it might have to be called Emitters(0) not Emitters(2). Not 100% sure but at least the last time I had that wrong it gave me an error while compiling. Not sure how it is with only 1 emitter.

 

[ChairmanMurder[Forge]]

What I was wondering was what sprite/emitter would I summon? The

Emitters(2)=SpriteEmitter'WTF.WTFEquipAFS12ExplosiveRoundEmitter.Blast'

points to a something in the WTF sprites/models/whatever, and I don't want to inflict downloads from my measly 2mbps server. I just want the effect to look like the sparks you get when you shoot something metal, or a different emitter is someone has any suggestions. Something that has a little more oomph, you know, since I'm firing explosive rounds.


And goddammit this weapon is so frigtastically overpowered. I love it. Now there's something to kill the eight people's worth of zeds and Doom beasties.

 

[ChairmanMurder[Forge]]

Okaydokes. I deleted all WTFMod related files, put

Emitters(0)=SpriteEmitter'Blast'

In the relevant spot, and it seems to be throwing up some nice effects upon impact. I didn't need to download anything and I didn't get any errors, so I assume it's a purely code effect. When I uploaded to server it seemed fine there, too.

No way for me to be 100% sure until I get some of my clan people to try it out, but I'm pretty sure we're golden on this. Thanks for all the help, guys.

 

[HaTeMe]

Okaydokes. I deleted all WTFMod related files, put

Emitters(0)=SpriteEmitter'Blast'

In the relevant spot, and it seems to be throwing up some nice effects upon impact. I didn't need to download anything and I didn't get any errors, so I assume it's a purely code effect. When I uploaded to server it seemed fine there, too.

No way for me to be 100% sure until I get some of my clan people to try it out, but I'm pretty sure we're golden on this. Thanks for all the help, guys.

What I did to create a custom effect on impact was simply make a custom emitter in the SDK and then copy/pasted it on a notepad, then copied the code from there into my weapon and it was called something like "SpriteEmitter1" and at the bottom saying "Emitters(0)=SpriteEmitter'SpriteEmitter1'" and everything worked fine so it should work the way you put it.

From what I can tell, it CREATES the emitter there, it doesnt load it up from anywhere. The only part it loads is the possible sprite/texture you used and in this case its the "kf_fx_trip_t.Misc.smoke_animated" which is already in the game.

 

[lerson]

Does anyone perchance know how I would go about using this explosive rounds code in a manner that the Demo exclusively gets explosive rounds on a weapon without it being a different weapon entirely?

 

[ChairmanMurder[Forge]]

Take a look at the code from the WTFmod. This is the code for the ASF12 (the specific file is WTFEquipAFS12Fire.UC), which changes to explosive rounds when wielded by a Demo.

Spoiler!

class WTFEquipAFS12Fire extends AA12Fire;

//from kfshotgunfire
function DoFireEffect()
{
    local Vector StartProj, StartTrace, X,Y,Z;
    local Rotator R, Aim;
    local Vector HitLocation, HitNormal;
    local Actor Other;
    local int p;
    local int SpawnCount;
    local float theta;
	local KFPlayerReplicationInfo KFPRI;

    Instigator.MakeNoise(1.0);
    Weapon.GetViewAxes(X,Y,Z);

    StartTrace = Instigator.Location + Instigator.EyePosition();// + X*Instigator.CollisionRadius;
    StartProj = StartTrace + X*ProjSpawnOffset.X;
    if ( !Weapon.WeaponCentered() && !KFWeap.bAimingRifle )
	    StartProj = StartProj + Weapon.Hand * Y*ProjSpawnOffset.Y + Z*ProjSpawnOffset.Z;

    // check if projectile would spawn through a wall and adjust start location accordingly
    Other = Weapon.Trace(HitLocation, HitNormal, StartProj, StartTrace, false);

// Collision attachment debugging
 /*   if( Other.IsA('ROCollisionAttachment'))
    {
    	log(self$"'s trace hit "$Other.Base$" Collision attachment");
    }*/

    if (Other != None)
    {
        StartProj = HitLocation;
    }

    Aim = AdjustAim(StartProj, AimError);

	ProjectileClass=default.ProjectileClass;
	ProjPerFire=default.ProjPerFire;
	KFPRI = KFPlayerReplicationInfo(Instigator.PlayerReplicationInfo);
	if (KFPRI != none)
	{
		[color=yellow]if (KFPRI.ClientVeteranSkill == Class'WTFPerksDemolitions')
		{
			ProjPerFire=1;
			ProjectileClass=Class'WTF.WTFEquipAFS12ExplosiveRound';
			if( KFWeap.bAimingRifle )
			{
				Spread *= 0.35; //bigger bonus for aiming
			}
			else
			{
				Spread *= 0.6;
			}
		}
	}[/color]
	
    SpawnCount = Max(1, ProjPerFire * int(Load));

    switch (SpreadStyle)
    {
    case SS_Random:
        X = Vector(Aim);
        for (p = 0; p < SpawnCount; p++)
        {
            R.Yaw = Spread * (FRand()-0.5);
            R.Pitch = Spread * (FRand()-0.5);
            R.Roll = Spread * (FRand()-0.5);
            SpawnProjectile(StartProj, Rotator(X >> R));
        }
        break;
    case SS_Line:
        for (p = 0; p < SpawnCount; p++)
        {
            theta = Spread*PI/32768*(p - float(SpawnCount-1)/2.0);
            X.X = Cos(theta);
            X.Y = Sin(theta);
            X.Z = 0.0;
            SpawnProjectile(StartProj, Rotator(X >> Aim));
        }
        break;
    default:
        SpawnProjectile(StartProj, Aim);
    }

	if (Instigator != none && Instigator.Physics != PHYS_Falling)
		Instigator.AddVelocity(KickMomentum >> Instigator.GetViewRotation());
}

defaultproperties
{
     ProjectileClass=Class'WTF.WTFEquipAFS12ForceBullet'
}

I'm not sure as to how the actual programming language works, but the highlighter portion is what switches the gun to explosive rounds based on perk.

 

[HaTeMe]

Does anyone perchance know how I would go about using this explosive rounds code in a manner that the Demo exclusively gets explosive rounds on a weapon without it being a different weapon entirely?

Im guessing youd have to edit the weapon code for each weapon separately which is basically like making your own weapon. Unless someone more experienced has a workaround.

 

[FluX]

Im guessing youd have to edit the weapon code for each weapon separately which is basically like making your own weapon. Unless someone more experienced has a workaround.

For what i've learnt so far, this is the way to do it. Only problem you'd probably have is whether you'd want to make these weapons replacement of the current weapon or as a seperate weapon.