[Help]Patriarch Mutator

[matttthias]

i need some help with this. i wanted to create a mutator that shows everyone who killed the patriarch but the message that appears is " The Patriarch was killed by someone!". but instead of "someone" should be the name of the player who has killed the patriarch

class PatriarchKillRules extends GameRules;

function PostBeginPlay()
{
    NextGameRules = Level.Game.GameRulesModifiers;
    Level.Game.GameRulesModifiers = Self;
}

function ScoreKill(Controller Killer, Controller Killed)
{
    local Controller C;
    local Pawn Target;
    
    if( PlayerController(Killer)!=None && ZombieBoss(Killed.Pawn)!=None )
    {
    for (C = Level.ControllerList; C != None; C = C.NextController)
    {
        if( C.bIsPlayer && C.Pawn!=None && PlayerController(C)!=None )
        {
            PlayerController(C).ReceiveLocalizedMessage(Class'MessageKill',,Target.Controller.PlayerReplicationInfo);
        }
    }
    }
    Super.ScoreKill(Killer,Killed);
}

defaultproperties
{
}

class MessageKill extends LocalMessage;

static function string GetString(
    optional int Switch,
    optional PlayerReplicationInfo RelatedPRI_1,
    optional PlayerReplicationInfo RelatedPRI_2,
    optional Object OptionalObject )
{
    return Default.Message@Eval(RelatedPRI_1!=None,RelatedPRI_1.PlayerName,"someone")$"!";
}

defaultproperties
{
     LifeTime=6.000000
     Message="The Name of the Patriarch-Killer is"
     DrawColor=(B=0,G=255,R=0)
}

class MutPatriarchHealth extends Mutator;

function PreBeginPlay()
{
    Spawn(Class'PatriarchKillRules');
    AddToPackageMap();
}

defaultproperties
{
     bAddToServerPackages=True
     GroupName="KF-Pat"
     FriendlyName="Patriach-Killer"
     Description="You can see who has killed the patriarch"
}

 

[Marco]

function ScoreKill( Controller Killer, Controller Killed )
{
    if( Killed!=None && ZombieBoss(Killed.Pawn)!=None )
    {
        if( Killer!=None )
            BroadcastLocalizedMessage(Class'MessageKill',,Killer.PlayerReplicationInfo);
        else BroadcastLocalizedMessage(Class'MessageKill');
    }
    Super.ScoreKill(Killer,Killed);
}

Simple as ABC huh?

 

[matttthias]

wow so easy... i love you

 

[simpleA]

matttthias, have you finished?

 

[matttthias]

yes i finished it and it's in use

 

[simpleA]

Could you publish it?

 

[matttthias]

here is the link where you can download it:
[url]http://www.gamefront.com/files/21151806/KFPatKiller.rar[/URL]

 

[simpleA]

Great, thx. But when i play in solo mode, each monster kill - it says: The Patriarch was killed by someone!

 

[matttthias]

sorry my bad because i copied it out of a whole mutator and created a new mutator.
fixed it:
[url]http://www.gamefront.com/files/21154918/KFPatKill.rar[/URL]

 

[simpleA]

It works. Thank you.

 

[slavek]

Should try to get this whitelisted, nice little misc mutator.

 

[Gartley]

Marco does it again.