[Help] Aimed Fire Only

[ro_sauce]

i'm trying to make my machineguns only able to fire in aiming only, not hip, so i took the code out of LAW and LAWFire, but it keeps going out of ironsights after each shot, and I cant figure out how to make it do this only when magammoremaining=0.

dp28weapon:

Spoiler!

class DP28 extends KFWeapon;

// Killing Floor's Light Anti Tank Weapon.
// This is probably about as badass as things get....

simulated event WeaponTick(float dt)
{
[COLOR=Red]    if(AmmoAmount(0) == 0)
        MagAmmoRemaining = 0;
    super.Weapontick(dt);[/COLOR]
}

/**
 * Handles all the functionality for zooming in including
 * setting the parameters for the weapon, pawn, and playercontroller
 *
 * @param bAnimateTransition whether or not to animate this zoom transition
 */
simulated function ZoomIn(bool bAnimateTransition)
{
    if( Level.TimeSeconds < FireMode[0].NextFireTime )
    {
        return;
    }

    super.ZoomIn(bAnimateTransition);

    if( bAnimateTransition )
    {
        if( bZoomOutInterrupted )
        {
            PlayAnim('Raise',1.0,0.1);
        }
        else
        {
            PlayAnim('Raise',1.0,0.1);
        }
    }
}


/**
 * Handles all the functionality for zooming out including
 * setting the parameters for the weapon, pawn, and playercontroller
 *
 * @param bAnimateTransition whether or not to animate this zoom transition
 */
simulated function ZoomOut(bool bAnimateTransition)
{
    super.ZoomOut(false);

    if( bAnimateTransition )
    {
        TweenAnim(IdleAnim,FastZoomOutTime);
    }
}

dp28Fire:

Spoiler!

class dp28fire extends kffire;

function bool AllowFire()
{
    if( Instigator != none && Instigator.IsHumanControlled() )
    {
        if( !KFWeapon(Weapon).bAimingRifle || KFWeapon(Weapon).bZoomingIn )
        {
            return false;
        }
    }
    [COLOR=Red]return ( Weapon.AmmoAmount(ThisModeNum) >= AmmoPerFire);[/COLOR]
}
function ServerPlayFiring()
{
    Super.ServerPlayFiring();
    KFWeapon(Weapon).ZoomOut(false);
}
function PlayFiring()
{
    Super.PlayFiring();
    KFWeapon(Weapon).ZoomOut(false);
}

do i need to post default props too for help?

 

[RuneHarle]

I'm looking at it from work and I'll be able to look more thuroughly in about 10 hours, but I noticed this immediately and it might be the cause.

Spoiler!

simulated function ZoomIn(bool bAnimateTransition)
{
    if( Level.TimeSeconds < FireMode[0].NextFireTime )
    {
        return;
    }
 
    super.ZoomIn(bAnimateTransition);
 
    if( bAnimateTransition )
    {
        if( bZoomOutInterrupted )
        {
            PlayAnim('Raise',1.0,0.1);
        }
        else
        {
            PlayAnim('Raise',1.0,0.1);
        }
    }
}

its calling the same transition if interupted or not

 

[ro_sauce]

and that would make it zoomout after each shot?

 

[RuneHarle]

and that would make it zoomout after each shot?

alright don't quote me but

Spoiler!

simulated function ZoomOut(bool bAnimateTransition)
{
    super.ZoomOut(false);

    if( bAnimateTransition )
    {
        TweenAnim(IdleAnim,FastZoomOutTime);
    }
}

I think that function is saying between all animations zoom out

try removing it

 

[ro_sauce]

hmm, nope it still zooms out after each shot, only faster now...

 

[RuneHarle]

try setting the zoom outs to true
(Still at work so I can't check the defaults and such for more clues/info)

 

[ro_sauce]

now it only fires when zoomed out....

 

[RuneHarle]

This is how a weapon without a flashlight would handle the weapontick, so maybe try this

Spoiler!

simulated function WeaponTick(float dt)
{
    local float LastSeenSeconds,ReloadMulti;

    if( bHasAimingMode && Instigator != none && Instigator.IsLocallyControlled() )
    {
        if ( bAimingRifle && Instigator!=None && Instigator.Physics==PHYS_Falling )
        {
            IronSightZoomOut();
        }
    }

     if ( (Level.NetMode == NM_Client) || Instigator == None || KFFriendlyAI(Instigator.Controller) == none && Instigator.PlayerReplicationInfo == None)
        return;

    UpdateMagCapacity(Instigator.PlayerReplicationInfo);

    if(!bIsReloading)
    {
        if(!Instigator.IsHumanControlled())
        {
            LastSeenSeconds = Level.TimeSeconds - Instigator.Controller.LastSeenTime;
            if(MagAmmoRemaining == 0 || ((LastSeenSeconds >= 5 || LastSeenSeconds > MagAmmoRemaining) && MagAmmoRemaining < MagCapacity))
                ReloadMeNow();
        }
    }
    else
    {
        if((Level.TimeSeconds - ReloadTimer) >= ReloadRate)
        {
            if(AmmoAmount(0) <= MagCapacity && !bHoldToReload)
            {
                MagAmmoRemaining = AmmoAmount(0);
                ActuallyFinishReloading();
            }
            else
            {
                if ( KFPlayerReplicationInfo(Instigator.PlayerReplicationInfo) != none && KFPlayerReplicationInfo(Instigator.PlayerReplicationInfo).ClientVeteranSkill != none )
                {
                    ReloadMulti = KFPlayerReplicationInfo(Instigator.PlayerReplicationInfo).ClientVeteranSkill.Static.GetReloadSpeedModifier(KFPlayerReplicationInfo(Instigator.PlayerReplicationInfo), self);
                }
                else
                {
                    ReloadMulti = 1.0;
                }

                AddReloadedAmmo();

                if( bHoldToReload )
                {
                    NumLoadedThisReload++;
                }

                if(MagAmmoRemaining < MagCapacity && MagAmmoRemaining < AmmoAmount(0) && bHoldToReload)
                    ReloadTimer = Level.TimeSeconds;
                if(MagAmmoRemaining >= MagCapacity || MagAmmoRemaining >= AmmoAmount(0) || !bHoldToReload || bDoSingleReload)
                    ActuallyFinishReloading();
                else if( Level.NetMode!=NM_Client )
                    Instigator.SetAnimAction(WeaponReloadAnim);
            }
        }
        else if(bIsReloading && !bReloadEffectDone && Level.TimeSeconds - ReloadTimer >= ReloadRate / 2)
        {
            bReloadEffectDone = true;
            ClientReloadEffects();
        }
    }
}

OR
just remove the weapon tick altogether, provided you are calling back to KFWeapon, it would default to the above expressions.

 

[Entangler]

I think you've overcomplicated this one. Wouldn't it have sufficed to take just the iron sights check without any of the other stuff attached, shove it in AllowFire, and call it a day?

 

[ro_sauce]

which part is the ironsights check?
how do i add it in allow fire?
do i need a "else" in there?

 

[braindead]

Entangler is right RO, don't try and complicate it by using the LAW code, as that is set different to a standard machine gun.

Instead, base it off the AK or something and put this in your Fire code

function bool AllowFire()
{

        if( !KFWeapon(Weapon).bAimingRifle )
            return false;

	return Super.AllowFire();
}

That should stop firing when not in iron sight mode but may need checking

 

[ro_sauce]

what is a check?

 

[RuneHarle]

what is a check?

a check is where we tell the program to see if condition a is met before moving on, in this case

Spoiler!

function bool AllowFire() 
{
          if( !KFWeapon(Weapon).bAimingRifle )
             return false;
      return Super.AllowFire(); 
}

is checking to see if your not aiming the rifle, and if so it returns a an answer that says you cannot fire.

the bit afterward says that in all other cases where the above condition is not met, allow the fire based on the superclass's conditions.

-if I'm wrong feel free to correct me

 

[ro_sauce]

function bool = check?

 

[Gartley]

the check is the IF statment.

The function is a group of statements

function bool AllowFire()

bool - simple true/false yes/no on/off 1/0
AllowFire - Can the gun fire or not

{
        if( !KFWeapon(Weapon).bAimingRifle )
            return false;

	return Super.AllowFire();
}

{} Defines the function bounds
if( !KFWeapon(Weapon).bAimingRifle ) - reads as if the weapon is not (!) set as a weapon that needs to aimed (bAimingRifle) (defined by the weapons default properties) then say it's not allowed to fire (return false) end statment ( ; )
should the condition is not met (so the weapon is being aimed) then tell the main weapon it can fire.

Hope that explains it. I just hope I got it right now I've gone to the trouble to expand on it.

 

[FluX]

the check is the IF statment.

The function is a group of statements

function bool AllowFire()

bool - simple true/false yes/no on/off 1/0
AllowFire - Can the gun fire or not

{
        if( !KFWeapon(Weapon).bAimingRifle )
            return false;
 
    return Super.AllowFire();
}

{} Defines the function bounds
if( !KFWeapon(Weapon).bAimingRifle ) - reads as if the weapon is not (!) set as a weapon that needs to aimed (bAimingRifle) (defined by the weapons default properties) then say it's not allowed to fire (return false) end statment ( ; )
should the condition is not met (so the weapon is being aimed) then tell the main weapon it can fire.

Hope that explains it. I just hope I got it right now I've gone to the trouble to expand on it.

That explaination is good mate don't worry. Well done on it - can tell you have been doing a little research again recently.

 

[ro_sauce]

thanks for the explanation, it really cleared a few things up for me, especially (!=non).

and the allowfire check works great.
now to figure out how to overheat barrels!

 

[RuneHarle]

maybe a check for how many times it has fired in a row without stopping?

 

[ro_sauce]

the code is in RO, i'm just having trouble sussing out how to make the parts i need work.
i'll start a separate thread for that when i get stuck again, i really appreciate everyone's help, and i think this gun pack will be quite enjoyable when all the stuff works.

i have been thinking of adjusting the damage and stuff to make a "ww2 weapons kf gungame", then i can port some maps from RO (berezina might be fun!, or danzig) to use in kf gungame.

 

[FluX]

thanks for the explanation, it really cleared a few things up for me, especially (!=non).

and the allowfire check works great.
now to figure out how to overheat barrels!

Just had a thought, check the Minigun out that you find in maps as it has a overheating system.