PC [v1080 Beta] Custom weapons no longer give dosh on zed kills

[Insert Name Here]

Category: Code

Reproducibility: Always

Summary: In the beta, mod weapons no longer give dosh on zed kills.

Description: This is caused by a new validation function added to KFGame.KFPawn in the beta, ValidateDamageForDamageHistory(). In the function above it, UpdateDamageHistory() (about lines 2807-2868, v1080 SDK), it uses this function (about line 2816) before adding the given damage to the zed's damage history. This damage history is used to distribute XP and dosh upon the zed's death in KFGame.KFGameInfo function DistributeMoneyAndXP() (about line 2410).

When using a custom weapon, however, it fails this validation check, causing the damage to not be added and thus not giving out XP or dosh to the player using this weapon. This is likely intentional for the XP side to prevent leveling exploits (though see P.S. below), but unintentional for the dosh side.

It is likely that, in order to fix this, this function will have to be moved to KFGameInfo.DistributeMoneyAndXP() as a final validator for giving out XP for a damage type, as the XP check is done after the dosh rewards.

Online/Offline: Both

P.S. For the XP side of this, make sure that any XP that would have been given is still routed through KFGame.KFPlayerController function OnPlayerXPAdded(). This is a mod notification function, and is necessary for some mods (e.g. ServerExt) to function properly. This might require KFGameInfo.AddPlayerXP() to do the validations itself.

 

[Insert Name Here]

Something else I want to mention: because failing this validation check exits UpdateDamageHistory() early, it also breaks zed aggro-switching (about lines 2840-2854) when using custom weapons.

 

[Yoshiro]

Added to our system, thanks!

 

[Freebase]

Issue still wasn't fixed in the official update

 

[Insert Name Here]

Issue still wasn't fixed in the official update

Correct. AFAIK this is in the system, but Yoshiro stated that the desired fix was too risky to implement for v1081 (what exactly that means, I don't know). I am working on some suggested SDK fixes to ensure that the validation works properly while still ensuring mod support for both custom zeds and weapons.

For now though, I have a workaround for zeds not giving dosh for custom weapons:

This can be done for both game modes and mutators. For custom KFGameInfo's (e.g. Zedternal, Classic Mode), the relevant function is ReduceDamage(). For custom KFMutator's (e.g. weapon packs, Unofficial Mod) it's NetDamage(). The below code uses NetDamage() because I'm using it for Unofficial Mod. Note that this also fixes zed aggro-switching with custom weapons.

Spoiler!

function NetDamage(int OriginalDamage, out int Damage, Pawn Injured, Controller InstigatedBy, vector HitLocation, out vector Momentum, class<DamageType> DamageType, Actor DamageCauser)
{
    local KFPawn_Monster KFPM;
    local DamageInfo Info;
    local Pawn BlockerPawn;
    local bool bChangedEnemies;
    local int HistoryIndex;
    local float DamageThreshold;
    local KFAIController KFAIC;

    // Call super first to ensure that
    // accurate damage is passed
    super.NetDamage(OriginalDamage, Damage, Injured, InstigatedBy, HitLocation, Momentum, DamageType, DamageCauser);
   
    KFPM = KFPawn_Monster(Injured);
    KFAIC = KFAIController(Injured.Controller);

    // Player-on-zed damage with custom weapon
    if (KFPM != None && KFAIC != None && KFPlayerController(InstigatedBy) != None && IsFromModWeapon(DamageType))
    {
        // Copy/paste modified from KFPawn.UpdateDamageHistory()
        if( !KFPM.GetDamageHistory( InstigatedBy, Info, HistoryIndex ) )
        {
            KFPM.DamageHistory.Insert(0, 1);
        }

        DamageThreshold = float(KFPM.HealthMax) * KFAIC.AggroPlayerHealthPercentage;

        KFPM.UpdateDamageHistoryValues( InstigatedBy, Damage, DamageCauser, KFAIC.AggroPlayerResetTime, Info, class<KFDamageType>(DamageType) );

        if( `TimeSince(KFPM.DamageHistory[KFAIC.CurrentEnemysHistoryIndex].LastTimeDamaged) > 10 )
        {
            KFPM.DamageHistory[KFAIC.CurrentEnemysHistoryIndex].Damage = 0;
        }

        if( KFAIC.IsAggroEnemySwitchAllowed()
            && InstigatedBy.Pawn != KFAIC.Enemy
            && Info.Damage >= DamageThreshold
            && Info.Damage > KFPM.DamageHistory[KFAIC.CurrentEnemysHistoryIndex].Damage )
        {
            BlockerPawn = KFAIC.GetPawnBlockingPathTo( InstigatedBy.Pawn, true );
            if( BlockerPawn == none )
            {
                bChangedEnemies = KFAIC.SetEnemy(InstigatedBy.Pawn);
            }
            else
            {
                bChangedEnemies = KFAIC.SetEnemy( BlockerPawn );
            }
        }

        KFPM.DamageHistory[HistoryIndex] = Info;
   
        if( bChangedEnemies )
        {
            KFAIC.CurrentEnemysHistoryIndex = HistoryIndex;
        }
    }
}

The contents of the IsFromModWeapon() function will vary depending on whether your mod weapons use custom KFDamageType's. Most weapon pack mods should, but mods that simply override vanilla weapons (e.g. Zedternal, Classic Mode, Unofficial Mod) will have to use more roundabout methods.

For weapons with custom damage types (replace MyPackage with your mod's package name but keep the single quotes):

Spoiler!

function bool IsFromModWeapon(class<DamageType> DmgType)
{
    return (DmgType != None && DmgType.GetPackageName() == 'MyPackage');
}

For weapons with vanilla damage types (note that this won't work if both the vanilla weapon and your mod weapon are in the Trader list):

Spoiler!

function bool IsFromModWeapon(class<DamageType> DmgType)
{
    local class<KFWeaponDefinition> WeapDef;

    // We only care about KF damage types here
    if (class<KFDamageType>(DmgType) == None)
        return false;
       
    WeapDef = class<KFDamageType>(DmgType).default.WeaponDef;

    // The logic here is that if the original
    // WeaponDef is not in the Trader list,
    // it was replaced by a mod weapon
    return (MyKFGI.MyKFGRI.TraderItems.SaleItems.Find('WeaponDef', WeapDef) == INDEX_NONE);
}

For the latter version, this can be very expensive to check the Trader list for each damage event, so using a mod-specific method of checking if the damage came from a mod weapon is preferred.

 

[Flammable4444]

So it's still not officialy fixed right? Because it's the bug that i recently noticed on my own, and i asked few modders, and they confirmed this. This is the only thread about this issue, but i'm not a modder, and i dont understand how to implement this fixes into my server. Can you guys explain how to fix this bug? If it possible to. I can edit my custom weapons if needed.